通常、Accessのフォームやレポートを最大化表示する場合は

DoCmd.Maximize

を使用しますが、DoCmd.Maximizeを使用しないでAccessのメインウィンドと同じ大きさでフォームやレポートを表示する方法を紹介します。
Accessのメインウィンドとは、下記に記すようにAccessを開いたときのグレーの部分をいいます。

mainwindow
【注意】
下記プログラムはWin32APIを使用しています。使用するときは必ず自己責任で使用するようお願いします。


標準モジュール
オブジェクトから新規モジュールを選択して下記プログラムを入力します。

'指定された文字列と一致するクラス名とウィンドウ名文字列を持つ
'ウィンドウのハンドルを取得
Declare Function FindWindowEX Lib "user32.dll" Alias "FindWindowExA"
(ByVal hwndParent As Long, ByVal hwndChildAfter As Long, _
ByVal lpszClass As String, ByVal lpszWindow As String) As Long

'ウィンドウのクライアント領域の寸法を取得する関数の宣言
Declare Function GetClientRect Lib "user32.dll" _
(ByVal hwnd As Long, lpRect As RECT) As Long

'長方形の左上隅と右下隅の座標を定義する構造体
Type RECT
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type

'クライアント領域に対するデバイスコンテキストのハンドルを取得
Declare Function GetDC Lib "user32" (ByVal hwnd As Long) As Long

'指定デバイスに固有の情報を取得
Declare Function GetDeviceCaps Lib "gdi32" _ (ByVal hdc As Long, ByVal nIndex As Long) As Long
Public Const LOGPIXELSX = 88
Public Const LOGPIXELSY = 90

クラスモジュール
標準モジュールを入力した後は、VBAの「挿入」−「クラスモジュール」でクラスモジュールを新規に作成します。作成したクラスモジュールに下記プログラムを入力します。
入力後、このクラスモジュールだけは「clsSetWindSize」の名前で保存してください。

Private Const TPI As Integer = 1440

Private m_Left As Integer
Private m_Top As Integer
Private m_Right As Integer
Private m_Bottom As Integer

Public Function SetWindSize()

' メインウィンドの座標を取得
Dim lngAccessHandle As Long
Dim lngResult As Long
Dim rct As RECT
Dim lngPixelsX As Long
Dim lngPixelsY As Long

'このAccessのウィンドウハンドルを取得
lngAccessHandle = Application.hWndAccessApp

'Accessのメインウィンド(グレーの部分)のハンドルを取得
lngAccessHandle = FindWindowEX(lngAccessHandle, 0, "MDIClient", vbNullString)

' ウィンドウハンドルを取得できたときは
If lngAccessHandle <> 0 Then
'スクリーン全体のデバイスコンテキストのハンドルを取得
lngResult = GetDC(0)

'画面の水平・垂直方向の1インチ当たりのピクセル数を取得
lngPixelsX = GetDeviceCaps(lngResult, LOGPIXELSX)
lngPixelsY = GetDeviceCaps(lngResult, LOGPIXELSY)
'Accessのメインウィンドウの寸法を取得
lngResult = GetClientRect(lngAccessHandle, rct)

'取得した寸法を格納
With rct
m_Left = (.Left / lngPixelsX) * TPI
m_Top = (.Top / lngPixelsY) * TPI
m_Right = (.Right / lngPixelsX) * TPI
m_Bottom = (.Bottom / lngPixelsY) * TPI
End With
End If
End Function

Public Property Get Right() As Long
' メインウィンドのX座標
Right = m_Right
End Property

Public Property Get Bottom() As Long
' メインウィンドのX座標
Bottom = m_Bottom
End Property

フォーム
オブジェクトからフォームまたはレポートを新規に作成し、フォーム(レポート)の「開く時」のイベントプロシージャに下記プログラムを入力します。

Private Sub Form_Open(Cancel As Integer)

Dim cWindSize As clsSetWindSize

Set cWindSize = New clsSetWindSize

With cWindSize
.SetWindSize
DoCmd.MoveSize 0, 0, .Right, .Bottom
End With

Set cWindSize = Nothing

End Sub 

上記プログラムを入力した後、フォーム(レポート)を開くとメインウィンド全体に表示されます。